Rumus Excel Penjumlahan dengan Kriteria

Rumus Excel Penjumlahan dengan Kriteria

oleh

Excel menyediakan beberapa fungsi yang bisa menghitung dengan kriteria, baik satu maupun lebih dari satu kriteria.

Misalnya terdapat data ketersediaan mobil bekas di sebuah showroom berdasarkan merek, tipe, dan jumlah stok. Dengan data tersebut, kita dapat melakukan penjumlahan berdasarkan berbagai kombinasi kriteria.

Rumus Excel Penjumlahan dengan 1 Kriteria

Pertanyaan:

Berapakah total mobil merek “Toyota” yang tersedia?

Untuk menjumlahkan data dengan satu kriteria, gunakan fungsi SUMIF.

Langkah-langkah:

  • Letakkan kursor di sel F4.
  • Ketik fungsi SUMIF.
  • Parameter range diisi dengan rentang yang berisi merek mobil.
  • Parameter criteria diisi dengan “Toyota”.
  • Parameter sum_range diisi dengan rentang jumlah mobil.

Rumus:

=SUMIF(B2:B21,"Toyota",D2:D21)

Hasilnya menunjukkan bahwa total mobil bekas merek Toyota yang tersedia adalah 16 unit.

Rumus Excel Penjumlahan dengan 2 Kriteria atau Lebih

Pertanyaan:

Berapakah total mobil merek “Honda” dengan tipe “Sedan”?

Untuk penjumlahan dengan dua atau lebih kriteria, gunakan fungsi SUMIFS.

Hal yang perlu diperhatikan:

  1. Fungsi SUMIFS tersedia mulai Excel 2007.
  2. Semua kriteria harus terpenuhi agar data dijumlahkan.

Langkah-langkah:

  • Letakkan kursor di sel F4.
  • Ketik fungsi SUMIFS.
  • sum_range berisi jumlah mobil.
  • criteria_range1 berisi merek mobil.
  • criteria1 diisi “Honda”.
  • criteria_range2 berisi tipe mobil.
  • criteria2 diisi “Sedan”.

Rumus:

=SUMIFS(D2:D21,B2:B21,"HONDA",C2:C21,"SEDAN")

Hasilnya menunjukkan bahwa jumlah mobil sedan merek Honda yang tersedia adalah 5 unit.

Rumus Excel Penjumlahan dengan 2 Kriteria atau Lebih (Alternatif untuk Excel Lama)

Jika menggunakan Excel versi sebelum 2007, fungsi SUMIFS tidak tersedia.

Solusinya adalah menggunakan:

  • Fungsi AND
  • Kolom bantuan
  • Fungsi SUMIF

Membuat Kolom Bantuan

Masukkan rumus berikut di kolom bantuan:

=AND(B2="HONDA",C2="SEDAN")

Salin rumus ke seluruh baris data.

Menjumlahkan Data

Gunakan rumus:

=SUMIF(E2:E21,TRUE,D2:D21)

Hasilnya tetap 5 unit, sama seperti menggunakan SUMIFS.

Rumus Excel Penjumlahan dengan Banyak Kriteria yang Tidak Harus Terpenuhi Semua

Pertanyaan:

Berapakah jumlah mobil merek “Toyota” dan “Honda”?

Kasus ini tidak dapat diselesaikan dengan SUMIFS karena satu baris data tidak mungkin memiliki dua merek sekaligus.

Walaupun menggunakan kata “dan”, logikanya sebenarnya adalah:

Toyota ATAU Honda

Menggunakan Fungsi OR

Buat kolom bantuan dengan rumus:

=OR(B2="Toyota",B2="Honda")

Salin ke seluruh data.

Kemudian gunakan:

=SUMIFS(D2:D21,E2:E21,TRUE)

Hasilnya adalah 29 unit mobil.

Rumus Excel Penjumlahan dengan Banyak Kriteria Tanpa Kolom Bantuan

Jika tidak ingin menggunakan kolom bantuan, gunakan fungsi SUMPRODUCT.

Rumus:

=SUMPRODUCT(((B2:B21="Toyota")+(B2:B21="Honda")>0)*D2:D21)

Tekan Enter setelah mengetik rumus.

Hasilnya tetap 29 unit, sama seperti metode sebelumnya, tetapi tanpa memerlukan kolom tambahan.

Kesimpulan

Excel menyediakan beberapa metode untuk melakukan penjumlahan berdasarkan kriteria:

  • SUMIF untuk satu kriteria.
  • SUMIFS untuk dua atau lebih kriteria yang semuanya harus terpenuhi.
  • AND + SUMIF sebagai alternatif pada Excel versi lama.
  • OR + SUMIFS untuk kriteria alternatif (ATAU).
  • SUMPRODUCT untuk menghindari penggunaan kolom bantuan.

Pemilihan rumus tergantung pada jumlah kriteria, versi Excel yang digunakan, dan apakah semua kriteria harus terpenuhi atau hanya salah satu saja.

Tinggalkan komentar